คู่มือเบื้องต้น Google sheet ที่ใครก็เอาไปใช้ได้ ตอนที่ 2 (รวมสูตรที่ใช้จริง)

ต่อจาก ตอนที่ 1 ที่เราพูดถึง วิธีการใช้งาน กันไปแล้ว ตอนนี้เราจะมาลงลึกที่ สูตร (Formula) ที่หยิบไปใช้ได้จริงกันบ้าง โดยจะเน้นสูตรที่สายการเงิน-การลงทุนได้ใช้บ่อยๆ ไม่ต้องจำหมดก็ได้ครับ ติดตรงไหนค่อยกลับมาเปิดดูทีหลังได้เลย แค่เข้าใจ และถาม AI ก็ใช้เป็นแล้ว เอาไว้ตรวจสูตรปรับให้้เข้ามือ และหวังว่าบทความนี้จะมีประโยชน์ครับ

เรามีชีตตัวอย่างที่รวมสูตรในบทความนี้ เปิดชีตตัวอย่างได้ปุ่มเขียวใช้งาน แล้วกดทำสำเนา (Make a copy) เพื่อเอาไปลองทำความเข้าใจของตัวเอง

สารบัญ

• Part 1 — สูตรตรรกะ: IF, IFS, IFERROR
• Part 2 — ค้นหา/ดึงข้อมูล: VLOOKUP, XLOOKUP, INDEX+MATCH
• Part 3 — นับ/รวมแบบมีเงื่อนไข: SUMIF, COUNTIF, AVERAGEIF
• Part 4 — สูตรพลังสูง: ARRAYFORMULA, QUERY, FILTER, IMPORTRANGE
• Part 5 — สายการเงิน-ลงทุน: GOOGLEFINANCE, FV/PMT
• Part 6 — ข้อความ & วันที่
• Part 7 — Pivot Table
• Part 8 — ดึงข้อมูลจากเว็บ/API: IMPORTDATA/HTML/XML
• Part 9 — Apps Script
• ตัวอย่างชีตเป็นไอเดีย เอาไปทำตามได้
• ต่อยอดด้วย AI

.
.
.

มาเริ่มกันนน

.
.
.

Part 1: ถ้า…ให้…

1. IF — ถ้าเงื่อนไขจริง ทำอย่างนึง ไม่จริงทำอีกอย่าง
รูปแบบคือ
IF(เงื่อนไข, ถ้าจริง, ถ้าไม่จริง)
เหมาะกับการติดป้ายข้อมูล เช่น กำไรหรือขาดทุน

=IF(B2>0, "กำไร", "ขาดทุน")
=IF(C2>=100000, "ถึงเป้า", "ยังไม่ถึง")

ทริคยอดฮิต:
IF + NOT(ISBLANK()) คำนวณเฉพาะแถวที่กรอกข้อมูลแล้ว
ปัญหาคลาสสิกคือลากสูตรเผื่อไว้ทั้งคอลัมน์ แล้วแถวที่ยังไม่กรอกขึ้นเลข 0 หรือ error เต็มไปหมด แก้ด้วยการเช็คก่อนว่าช่องนั้น "ไม่ว่าง" ค่อยคำนวณ

=IF(NOT(ISBLANK(B2)), B2*C2, "")

อ่านว่า "ถ้า B2 ไม่ว่าง ให้คำนวณ B2×C2 ไม่งั้นปล่อยว่าง" — ตารางจะสะอาด ไม่มี 0 รกตา (จะเขียนสั้นๆ ว่า =IF(B2<>"", B2*C2, "") ก็ได้ความหมายเดียวกัน)

2. IFS — เงื่อนไขหลายชั้น (ไม่ต้องซ้อน IF)
แทนที่จะเขียน IF ซ้อน IF จนตาลาย ใช้ IFS อ่านง่ายกว่า
ทริค: TRUE ตัวสุดท้ายคือ “กรณีอื่นๆ ที่เหลือ” เอาไว้เป็น default

=IFS(A2>=80,"A", A2>=70,"B", A2>=60,"C", TRUE,"ตก")

3. IFERROR — กันสูตรพังเป็น #ERROR
เวลาสูตรหารด้วยศูนย์ หรือหาค่าไม่เจอ มันจะขึ้น error น่าเกลียด ใช้ IFERROR ครอบไว้ให้แสดงค่าที่เราอยากได้แทน

=IFERROR(A2/B2, 0)
=IFERROR(VLOOKUP(...), "ไม่พบข้อมูล")

Part 2: สูตรค้นหา/ดึงข้อมูล (ใช้บ่อยสุด)

4. VLOOKUP — ค้นหาตามแนวตั้ง (ใช้บ่อยที่สุดตัวนึง)
นี่คือสูตรที่คนทำชีตการเงินใช้กันแทบทุกไฟล์ หน้าที่ของมันคือ เอาค่าตัวนึงไปหาในตารางอื่น แล้วดึงข้อมูลที่อยู่แถวเดียวกันกลับมา เช่น มีรหัสหุ้น อยากได้ชื่อบริษัท หรือมีรหัสสินค้า อยากได้ราคา

รูปแบบเต็มมี 4 ช่อง:

=VLOOKUP(ค่าที่หา, ช่วงตาราง, คอลัมน์ที่จะเอา, [ยอมให้คลาดเคลื่อนไหม?])

• ค่าที่หา = สิ่งที่เรากำลังตามหา (เช่น รหัสหุ้นในช่อง A2)
• ช่วงตาราง = ตารางฐานข้อมูลที่จะไปหา โดยคอลัมน์ซ้ายสุดของช่วงต้องเป็นคอลัมน์ที่เก็บค่าที่เราหา
• คอลัมน์ที่จะเอา = นับเป็นเลข เริ่มที่ 1 จากซ้ายสุดของช่วง (ไม่ใช่ชื่อคอลัมน์ A B C ของชีต)
• ยอมให้คลาดเคลื่อนไหม? = ใส่ FALSE (หรือ 0) = หาตรงเป๊ะ / TRUE = หาแบบใกล้เคียง

ตัวอย่าง สมมติมีชีตชื่อ ฐานข้อมูล เก็บ รหัส(A) / ชื่อ(B) / ชื่อบริษัท(C) / ราคา(D)

=VLOOKUP(A2, 'ฐานข้อมูล'!A:D, 3, FALSE)   // เอาชื่อบริษัท (คอลัมน์ที่ 3 ของช่วง)

กฎเหล็กที่คนพลาดบ่อย:

1. ใส่ FALSE (หรือ 0) ท้ายสุดเสมอ ไม่งั้นค่าจะเพี้ยนแบบหาสาเหตุไม่เจอ
2. VLOOKUP หาได้แค่ทาง "ขวา" ของคอลัมน์ที่หาเท่านั้น ถ้าอยากดึงค่าทางซ้ายให้ใช้ XLOOKUP หรือ INDEX+MATCH (ข้อ 5–6) แทน
3. อย่าลืม! ล็อกช่วงตารางด้วย $ (เช่น $A:$D) ก่อนลากสูตร ไม่งั้นช่วงจะเลื่อนตาม

เคล็ดลับใช้คู่ IFERROR กันค่าที่หาไม่เจอขึ้น #N/A:

=IFERROR(VLOOKUP(A2, 'ฐานข้อมูล'!$A:$D, 3, FALSE), "ไม่พบรหัสนี้")

ลองเปลี่ยนรหัสในช่องสีเหลือง (B9) จะเห็น VLOOKUP, XLOOKUP, INDEX+MATCH ทำงานเทียบกันในจอเดียว

5. XLOOKUP — รุ่นอัปเกรดของ VLOOKUP
ยืดหยุ่นกว่า หาได้ทั้งซ้ายขวา และใส่ค่า “ถ้าไม่เจอ” ได้ในตัว
รูปแบบ XLOOKUP(ค่าที่หา, ช่วงที่หา, ช่วงที่เอาผล, "ถ้าไม่เจอ")

=XLOOKUP(A2, 'ฐานข้อมูล'!A:A, 'ฐานข้อมูล'!C:C, "ไม่พบ")

6. INDEX + MATCH — ค้นหาแบบยืดหยุ่นสุด
คลาสสิกที่ทำได้ทุกทิศทาง MATCH หาว่าอยู่แถวไหน แล้ว INDEX ดึงค่าออกมา เขียนเยอะหน่อยอาจจะเข้าใจยาก ใช้มาก sheet จะช้า

=INDEX(C:C, MATCH(A2, A:A, 0))

Part 3: สูตรนับ/รวมแบบมีเงื่อนไข (ใช้บ่อยพวกรวมเงิน รวม port)

สามสูตรในพาร์ทนี้ทำงานคล้ายกัน คือ ดูเงื่อนไขก่อน แล้วค่อย รวม/นับ/เฉลี่ย เฉพาะแถวที่เข้าเงื่อนไข

7. SUMIF / SUMIFS — รวมเฉพาะที่เข้าเงื่อนไข
เช่น อยากรวมยอดเฉพาะหมวด "อาหาร" หรือเฉพาะเดือนนี้

=SUMIF(B:B, "อาหาร", C:C)
=SUMIFS(C:C, B:B, "อาหาร", A:A, ">="&DATE(2026,2,1))

• ดูคอลัมน์ B ทุกแถวที่เป็น "อาหาร" แล้วรวมเงินในคอลัมน์ C
• SUMIFS เพิ่มเงื่อนไขที่สอง ต้องเป็น "อาหาร" และ วันที่ตั้งแต่ 1 ก.พ. 2026 เป็นต้นไป

8. COUNTIF / COUNTIFS — นับแบบมีเงื่อนไข
เหมือน SUMIF แต่เปลี่ยนจาก "รวมเงิน" เป็น "นับจำนวนแถว"

=COUNTIF(B:B, "อาหาร")
=COUNTIFS(B:B, "อาหาร", C:C, ">100")

• นับว่ามีรายการหมวด "อาหาร" กี่ครั้ง
• นับเฉพาะหมวด "อาหาร" ที่จ่ายเกิน 100 บาท

9. AVERAGEIF — เฉลี่ยเฉพาะที่เข้าเงื่อนไข

=AVERAGEIF(B:B, "อาหาร", C:C)

• เอาเฉพาะหมวด "อาหาร" มาหาค่าเฉลี่ย

ตัวอย่างจริง — ชีตบันทึกรายรับรายจ่าย (ข้อมูลดิบ) แล้วสรุปอัตโนมัติด้วยสูตรกลุ่มนี้:

Part 4: สูตรที่ใช้เป็นแล้วชีวิตจะดี

10. ARRAYFORMULA — ไม่ต้องลากสูตรทุกแถว

สูตรคนขี้เกียจลาก (ทำช่องเดียวทั้งคอลัมน์)
แนะนำกันพลาดลืมลากสูตร!!
ใส่สูตรครั้งเดียวที่หัว แล้วมันคำนวณให้ทั้งคอลัมน์เอง เวลาเพิ่มข้อมูลใหม่ก็ไม่ต้องลากซ้ำ

=ARRAYFORMULA(IF(A2:A="", "", B2:B*C2:C))

จุดสำคัญคือ พอครอบด้วย ARRAYFORMULA เราจะอ้างถึง ทั้งช่วง (A2:A, B2:B, C2:C) แทนที่จะเป็นช่องเดียว (A2, B2, C2) แล้วสูตรจะไล่คำนวณให้ทุกแถวเองทีละแถว อ่านสูตรนี้ทีละท่อนได้ว่า:

• A2:A="" ไล่เช็คทุกแถวในคอลัมน์ A ว่า "ว่างไหม"
• ถ้าว่าง → คืนค่าว่าง "" (กันไม่ให้แถวที่ยังไม่กรอกขึ้น 0 หรือ error เต็มคอลัมน์ เหมือนทริค IF + ISBLANK ในข้อ 1)
• ถ้าไม่ว่าง → คำนวณ B2:B*C2:C คือเอา จำนวน × ราคา ของแถวนั้น

พิมพ์ครั้งเดียวที่ช่อง D2 ช่องเดียว ที่เหลือ D3, D4, D5... มันเติมให้เองหมด เพิ่มข้อมูลแถวใหม่กี่แถวก็ไหลตามทันที ไม่ต้องลากสูตรซ้ำ

หมายเหตุ: ช่องด้านล่าง (D3 ลงไป) ต้องว่างพอให้สูตรขยายลงไปได้ ถ้าเผลอไปพิมพ์อะไรทับไว้ มันจะขึ้น error #REF! (เพราะสูตรเขียนทับของเดิมไม่ได้) ให้เคลียร์ช่องด้านล่างออกก่อน

11. QUERY — เหมือนเขียนคำสั่งฐานข้อมูลในชีต (ใช้บ่อยมากกับงานสรุป)

ถ้าทำชีตจัดการเงินจริงจัง ทำได้ทั้ง กรอง + เลือกคอลัมน์ + จัดกลุ่ม + รวมยอด + เรียงลำดับ จบในสูตรเดียว แทนที่จะต้องใช้ SUMIF หลายตัวหรือทำ Pivot

รูปแบบ:

=QUERY(ช่วงข้อมูล, "คำสั่ง", จำนวนแถว header)

"คำสั่ง" เขียนคล้ายภาษา SQL โดยอ้างถึงคอลัมน์ด้วย ตัวอักษรของชีต (A, B, C...) ในเครื่องหมายคำพูด

คำสั่งที่ใช้บ่อย (เรียงตามลำดับการเขียน):

• select = เลือกว่าจะเอาคอลัมน์ไหนบ้าง (select * = เอาทั้งหมด)
• where = กรองเงื่อนไข
• group by = จัดกลุ่มเพื่อสรุปยอด
• order by = เรียงลำดับ (desc = มากไปน้อย)
• limit = เอากี่แถว

ตัวอย่างจากง่ายไปยาก สมมติข้อมูล วันที่(A) / หมวด(B) / ประเภท(C) / จำนวนเงิน(D):

// 1. กรองเฉพาะรายการที่เป็น "ซื้อ"
=QUERY(A:D, "select * where C='ซื้อ'", 1)

// 2. กรองตามวันที่ (สังเกตคำว่า date และรูปแบบ yyyy-mm-dd)
=QUERY(A:D, "select A, B, D where A >= date '2026-01-01'", 1)

// 3. สรุปยอดรวมแยกตามหมวด เรียงจากมากไปน้อย
=QUERY(A:D, "select B, sum(D) where C='ซื้อ' group by B order by sum(D) desc", 1)

// 4. ดึงค่าจากไฟล์อื่นมา query ต่อได้ด้วย
=QUERY(IMPORTRANGE("ลิงก์", "ชีต!A:D"), "select Col2, sum(Col4) group by Col2", 1)

จุดที่คนพลาดบ่อย:

1. เลข 1 ท้ายสุด = บอกว่ามี header 1 แถว (ถ้าไม่ใส่ บางทีหัวตารางจะหลุดมาปนกับข้อมูล)
2. ค่าข้อความใน where ต้องครอบด้วย เครื่องหมาย single quote ' เช่น 'ซื้อ' ส่วนวันที่ต้องนำหน้าด้วย date เช่น date '2026-01-01'
3. ถ้าข้อมูลมาจาก IMPORTRANGE ให้อ้างคอลัมน์เป็น Col1, Col2... แทน A, B

สูตรเดียวจบ — กรอง (จ่าย) + จัดกลุ่ม (หมวด) + รวมยอด + เรียงลำดับ

12. FILTER — กรองข้อมูลออกมาเป็นตารางใหม่อัตโนมัติ (ใช้บ่อยคู่กับ QUERY)
ถ้า QUERY ซับซ้อนไป FILTER คือทางเลือกที่เขียนง่ายกว่า หน้าที่คือ "ดึงเฉพาะแถวที่เข้าเงื่อนไข" ออกมาเป็นตารางใหม่ และมันอัปเดตเองทุกครั้งที่ข้อมูลต้นทางเปลี่ยน (ต่างจากตัวกรอง/Filter view ที่เป็นการซ่อนแถวเฉยๆ)

รูปแบบ:

=FILTER(ช่วงที่จะเอา, เงื่อนไข1, [เงื่อนไข2], ...)

ตัวอย่าง สมมติข้อมูล วันที่(A) / หมวด(B) / ประเภท(C) / จำนวนเงิน(D):

// 1. เอาเฉพาะแถวที่หมวดเป็น "อาหาร"
=FILTER(A:D, B:B="อาหาร")

// 2. หลายเงื่อนไขพร้อมกัน (และ) — เอาเฉพาะ "ซื้อ" ที่เกิน 1000
=FILTER(A:D, C:C="ซื้อ", D:D>1000)

// 3. เลือกเอาแค่บางคอลัมน์มาแสดง (เอาแค่ A กับ D)
=FILTER({A:A, D:D}, B:B="อาหาร")

ทริค:

• หลายเงื่อนไขในวงเล็บ FILTER = ต้องเข้าทุกข้อ (และ/AND) ถ้าอยากเป็น "หรือ" (OR) ให้ใช้เครื่องหมาย + คั่นเงื่อนไขในวงเล็บเดียว เช่น =FILTER(A:D, (B:B="อาหาร")+(B:B="เดินทาง"))
• ครอบ IFERROR กันกรณีไม่มีแถวไหนเข้าเงื่อนไข: =IFERROR(FILTER(...), "ไม่มีข้อมูล")
  
  FILTER คือสร้างตารางใหม่ที่อัปเดตเอง — ต่างจาก Filter view ที่แค่ซ่อนแถว

ประยุกต์ขั้นกว่า: รวมหลายชีตมาต่อกันเป็นตารางเดียว (FILTER + ต่อแถว)
จำเรื่อง "การรวมแถวต่อแถว" ด้วย {} และ ; จาก ตอนที่ 1 เอามาผสมกับ FILTER ได้สวยมาก สมมติเราแยกบันทึกสินทรัพย์เป็นหลายชีต (เงินสด / กองทุน / หุ้น) แล้วอยากรวมทุกชีตที่ "กรอกข้อมูลแล้ว" มาไว้หน้าสรุปแผ่นเดียว:

={
  FILTER('เงินสด'!A3:I, 'เงินสด'!H3:H<>"");
  FILTER('กองทุน'!A3:I, 'กองทุน'!H3:H<>"");
  FILTER('หุ้น'!A3:I,   'หุ้น'!H3:H<>"")
}

• 'เงินสด'!H3:H<>"" = เงื่อนไข "เอาเฉพาะแถวที่คอลัมน์ H ไม่ว่าง" (กันแถวเปล่าที่เผื่อไว้ไม่ให้ติดมาด้วย — หลักการเดียวกับทริค NOT(ISBLANK()) ข้อ 1)
• FILTER('เงินสด'!A3:I, ...) = ดึงข้อมูลชีตเงินสด คอลัมน์ A ถึง I เฉพาะแถวที่เข้าเงื่อนไข
• { ... ; ... ; ... } = เอาผลของแต่ละชีตมา ต่อกันในแนวตั้ง (เครื่องหมาย ; คือต่อแถว) กลายเป็นตารางใหญ่ตารางเดียว

ข้อควรระวัง: ทุกก้อนที่เอามาต่อด้วย ; ต้องมี จำนวนคอลัมน์เท่ากัน (ในตัวอย่างคือ A:I = 9 คอลัมน์ทุกชีต) ไม่งั้นจะ error

13. IMPORTRANGE — ดึงข้อมูลข้ามไฟล์
เชื่อมข้อมูลจากไฟล์ Google Sheet อีกไฟล์มาใช้ (ครั้งแรกต้องกดอนุญาตการเชื่อมต่อก่อน)

=IMPORTRANGE("ลิงก์หรือ ID ของไฟล์", "ชื่อชีต!A1:D100")

Part 5: สูตรสายการเงิน-การลงทุนโดยเฉพาะ

14. GOOGLEFINANCE — ดึงราคาหุ้น/อัตราแลกเปลี่ยนสดๆ
ดึงข้อมูลตลาดได้ตรงในชีตเลย (ส่วนใหญ่รองรับหุ้นต่างประเทศได้ดี หุ้นไทยบางตัวอาจไม่ครบ)

=GOOGLEFINANCE("NASDAQ:AAPL", "price")
=GOOGLEFINANCE("CURRENCY:USDTHB")

ใช้คู่กับการคำนวณต้นทุน/มูลค่าพอร์ตได้สบายๆ เช่นเอาราคาปัจจุบัน × จำนวนหุ้น

ราคาปัจจุบันดึงสดด้วย GOOGLEFINANCE, คอลัมน์มูลค่า/กำไรใช้ ARRAYFORMULA ใส่ครั้งเดียวทั้งคอลัมน์

15. สูตรการเงินสำเร็จรูป (FV, PV, PMT)
เอาไว้คำนวณดอกเบี้ยทบต้น เงินผ่อน หรือเป้าหมายการออม

=FV(อัตราต่องวด, จำนวนงวด, เงินที่ลงต่องวด)   // มูลค่าในอนาคต
=PMT(อัตราต่องวด, จำนวนงวด, เงินต้น)          // ค่างวดที่ต้องจ่าย

ถ้าดอกเบี้ยปีละ 6% ผ่อนรายเดือน ให้หารอัตราด้วย 12 และคูณจำนวนปีด้วย 12

ค่าที่ได้เป็นค่าประมาณเพื่อวางแผนเท่านั้น เพราะสูตรพวกนี้คิดบนสมมติฐานว่าอัตราดอกเบี้ย/ผลตอบแทน "คงที่เท่ากันทุกงวด" ซึ่งของจริงมันขยับขึ้นลงได้ และยังไม่รวมค่าธรรมเนียม ภาษี เงินเฟ้อ หรือจังหวะทบดอกที่ต่างกัน ตัวเลขจริงจากธนาคาร/สถาบันการเงินจึงคลาดเคลื่อนจากนี้ได้ ใช้เป็นภาพรวมไว้ตัดสินใจพอ อย่ายึดเป๊ะถึงหลักบาท

Part 6: สูตรจัดการข้อความ & วันที่ (จุกจิกแต่ช่วยได้เยอะ)

16. ข้อความ

=TRIM(A2)              // ตัดช่องว่างหัวท้าย
=A2 & " " & B2          // ต่อข้อความ (เครื่องหมาย &)
=LEFT(A2, 3)            // เอา 3 ตัวแรก
=SUBSTITUTE(A2,"-","")  // แทนที่ข้อความ

17. วันที่

=TODAY()                       // วันนี้
=YEAR(A2)  =MONTH(A2)          // แยกปี/เดือน
=EDATE(A2, 1)                  // บวกไป 1 เดือน
=DATEDIF(A2, TODAY(), "M")     // นับจำนวนเดือนระหว่างสองวัน

Part 7: Pivot Table — สรุปข้อมูลแบบลากวาง ไม่ต้องเขียนสูตร

ถ้า QUERY ดูยากไป Pivot คือทางลัด เหมาะกับการสรุปภาพรวมจากข้อมูลดิบเยอะๆ เช่น สรุปรายจ่ายแยกตามหมวด/เดือน หรือสรุปพอร์ตแยกตามกลุ่มหุ้น

วิธีใช้

1. คลุมช่วงข้อมูล (รวมหัวตาราง) แล้วไปที่เมนู แทรก (Insert) → Pivot table
2. เลือกว่าจะสร้างในชีตใหม่หรือชีตเดิม
3. ที่แผงด้านขวา ลากฟิลด์เข้าช่อง

• แถว (Rows) = สิ่งที่อยากจัดกลุ่ม เช่น "หมวดรายจ่าย"
• คอลัมน์ (Columns) = แตกย่อยอีกมิติ เช่น "เดือน"
• ค่า (Values) = ตัวเลขที่อยากสรุป เช่น "จำนวนเงิน" แล้วเลือกว่าจะ SUM / COUNT / AVERAGE
• ตัวกรอง (Filters) = กรองเฉพาะที่อยากดู
  
  ลากฟิลด์ "ประเภท/หมวด" เข้าช่องแถว และ "จำนวนเงิน" เข้าช่องค่า — สรุปได้โดยไม่ต้องเขียนสูตร

ทริค: คลิกขวาที่ค่าในตาราง Pivot เลือก "สรุปตาม" เปลี่ยนจาก SUM เป็น % ของทั้งหมดได้ เหมาะกับการดูสัดส่วนรายจ่าย

Part 8: ดึงข้อมูลจากเว็บ/API เข้าชีตอัตโนมัติ

นอกจาก IMPORTRANGE (ดึงข้ามไฟล์ชีต) Google Sheet ยังดึงข้อมูลจาก "ภายนอก" ได้ด้วย เหมาะกับคนที่อยากให้ตารางอัปเดตเองโดยไม่ต้องก๊อปวาง

18. IMPORTDATA — ดึงไฟล์ CSV/TSV จากลิงก์
ถ้าใครมีลิงก์ไฟล์ CSV (เช่นรายงานที่ export มาเป็นลิงก์สาธารณะ) ดึงเข้ามาทั้งตารางได้เลย

=IMPORTDATA("https://example.com/data.csv")

19. IMPORTHTML — ดึงตารางหรือลิสต์จากหน้าเว็บ
เว็บไหนที่ข้อมูลอยู่ในรูป "ตาราง" หรือ "ลิสต์" ดึงมาได้ตรงๆ เช่น ตารางสรุปจาก Wikipedia

=IMPORTHTML("ลิงก์เว็บ", "table", 1)   // เอาตารางที่ 1 ในหน้านั้น
=IMPORTHTML("ลิงก์เว็บ", "list", 2)    // เอาลิสต์ที่ 2

20. IMPORTXML — ดึงข้อมูลเฉพาะจุดด้วย XPath
ยืดหยุ่นสุดในกลุ่ม import เลือกหยิบเฉพาะค่าที่ต้องการจากหน้าเว็บได้ (ต้องรู้ XPath นิดหน่อย)

=IMPORTXML("ลิงก์เว็บ", "//div[@class='price']")

ข้อจำกัดที่ต้องรู้: สูตรกลุ่ม IMPORT เหล่านี้ดึงได้เฉพาะเว็บที่ "เปิดสาธารณะ" และโครงสร้างไม่ซับซ้อน เว็บที่ใช้ JavaScript โหลดข้อมูลทีหลัง (เช่นเว็บหุ้น/คริปโตหลายเจ้า) มักดึงไม่ได้ — กรณีแบบนั้นต้องไปพึ่ง API + Apps Script ใน Part ถัดไป

Part 9: Apps Script — สูตรทำไม่ได้ก็ต้องโค้ด

เมื่อสูตรเริ่มไม่พอ (เช่น ดึง API ที่ต้องใส่ key, ส่งอีเมลอัตโนมัติ, ทำงานตามเวลา) เราใช้ Apps Script ซึ่งเป็นการเขียนโค้ด (ภาษา JavaScript) สั่งงานชีตได้ ฟังดูยากแต่เริ่มจากของง่ายๆ ได้

วิธีเปิด
ไปที่เมนู ส่วนขยาย (Extensions) → Apps Script จะเปิดหน้าต่างเขียนโค้ดขึ้นมา

ตัวอย่าง: ดึงราคาคริปโตจาก API มาใส่ชีต
สร้างฟังก์ชันที่เรียกใช้เป็น "สูตรของเราเอง" ในชีตได้เลย

function getPrice(symbol) {
  const url = "https://api.example.com/price?symbol=" + symbol;
  const res = UrlFetchApp.fetch(url);
  const data = JSON.parse(res.getContentText());
  return data.price;
}

จากนั้นกลับมาที่ชีต พิมพ์ใช้ได้เหมือนสูตรปกติ

=getPrice("BTC")

อยากให้รันอัตโนมัติตามเวลา (Trigger)
ในหน้า Apps Script กดไอคอนรูปนาฬิกา (Triggers) → เพิ่มทริกเกอร์ → เลือกฟังก์ชันและความถี่ เช่น ทุกชั่วโมง/ทุกวัน ก็จะให้สคริปต์อัปเดตข้อมูลให้เองโดยไม่ต้องเปิดไฟล์

ตัวอย่างจริงที่เอาไปใช้ได้เลย — ชีต Investment Portfolio ดึงราคาหุ้น/กองทุน ตั้ง trigger ให้รันทุกเช้า ราคาในพอร์ตก็อัปเดตเองโดยไม่ต้องเปิดไฟล์ หรือจะต่อยอดแบบ ระบบติดตามหุ้น + แจ้งเตือน Telegram ที่ใช้ Apps Script + Trigger คอยเช็คราคาแล้วเด้งแจ้งเตือนเข้ามือถือให้อัตโนมัติก็ได้

ครั้งแรกที่รัน Google จะขออนุญาตการเข้าถึง (Authorization) ให้กดอนุญาตก่อน สคริปต์ถึงจะทำงานได้
เริ่มจากก๊อปโค้ดตัวอย่างมาปรับทีละนิดจะง่ายที่สุด ไม่ต้องเขียนเองทั้งหมดตั้งแต่แรก

ตัวอย่างชีตเป็นไอเดีย เอาไปทำตามได้

อ่านสูตรมาเยอะแล้ว จริงๆ สูตรพวกนี้เราเอาไปทำเป็นชีตใช้งานจริงไว้เพียบเลยครับ ลองกดเข้าไปดูว่าแต่ละสูตรถูกใช้จริงยังไง (ในบทความมีลิงก์ "ทำสำเนา" ให้ก๊อปไปใช้ได้เลย):

สาย SUMIF / QUERY — สรุปรายรับรายจ่าย & ปันผล

• วางแผนงบรายรับรายจ่าย (6 Jars) — แยกหมวดด้วย dropdown + สรุปยอดอัตโนมัติ
• เช็คสุขภาพการเงิน ฉบับมีกราฟ — สรุป + conditional formatting + กราฟ
• บันทึกจ่ายปันผล — SUMIF รวมปันผลรายหุ้น/รายเดือน

สาย GOOGLEFINANCE — ดึงราคาสด & ติดตามพอร์ต

• Investment Portfolio ดึงราคาหุ้น — รวมหุ้น/กองทุน/ทอง/คริปโตในที่เดียว
• คำนวณการปรับพอร์ต (Rebalance) — เทียบสัดส่วนปัจจุบัน vs เป้าหมาย
• ภาพรวมตลาดหุ้นโลก — S&P500 / NASDAQ / Nikkei / BTC

สาย FILTER — กรอง & จัดการรายการ

• หารตัง: หารเงินไม่ปวดหัว — แยกบิลทริปด้วย FILTER
• ติดตามการใช้บัตรเครดิต — จัดรายการหลายใบ + แจ้งเตือนรอบบิล

สาย FV / PMT — วางแผน & สินเชื่อ

• คำนวณเงินผ่อน กู้บ้าน/กู้ร่วม — PMT คิดค่างวด + ดอกเบี้ยลดต้นลดดอก

สาย IMPORT / Apps Script — ดึงข้อมูลนอก & อัตโนมัติ

• Investment Port V2.1 — IMPORTDATA ดึงราคากองทุน
• ระบบติดตามหุ้น + แจ้งเตือน Telegram — Apps Script + Trigger ส่งแจ้งเตือนเอง

ทุกชีตด้านบนกดเข้าไปในบทความจะมีลิงก์ทำสำเนา (Make a copy) ให้ก๊อปไปปรับใช้ได้เลย ไม่ต้องสร้างเองตั้งแต่ศูนย์

ทริคปิดท้าย

• กด Tab เพื่อเลือกสูตรที่ระบบแนะนำ จะเติมวงเล็บให้อัตโนมัติ
• ติดสูตรไหน เอาเมาส์ชี้ที่ชื่อสูตร จะมีคำอธิบายและตัวอย่างขึ้นมาให้อ่าน
• จำไม่ได้ไม่เป็นไร เปิด Google Sheets function list ค้นเอาได้ตลอด

มีอะไรแนะนำกันก็บอกมาได้เลยนะครับ สูตรพวกนี้เป็นแค่ส่วนหนึ่งที่ใช้บ่อย ลองหยิบไปผสมกันดูจะเจอลูกเล่นใหม่ๆ อีกเยอะเลย

ต่อยอดด้วย AI ให้ชีตทำได้ง่าย เร็วขึ้น

จุดสำคัญคือ ขอแค่เข้าใจพื้นฐานพวกนี้ก็พอ ไม่ต้องจำทุกสูตรให้ขึ้นใจ เพราะเดี๋ยวนี้เราเอา AI (เช่น ChatGPT, Gemini, Claude) มาเป็นผู้ช่วยทำชีตได้สบายมาก พอเรารู้ว่า "สูตรแต่ละแบบทำอะไรได้" เราจะ สั่งงานและตรวจคำตอบ AI ได้ถูก ทำให้งานเสร็จเร็วขึ้นหลายเท่า

ลองใช้แบบนี้ดูครับ:

• ให้มันเขียนสูตรให้ — บอกไปตรงๆ ว่าข้อมูลหน้าตาเป็นยังไง อยากได้ผลแบบไหน เช่น "ชีตมีคอลัมน์ วันที่/หมวด/จำนวนเงิน ช่วยเขียนสูตรสรุปยอดรวมแยกตามหมวดเฉพาะเดือนนี้ให้หน่อย"
• ให้มันแก้สูตรที่พัง — ก๊อปสูตรที่ error ไปถาม พร้อมบอกว่ามันขึ้น error อะไร มันจะช่วยไล่หาจุดผิดให้
• ให้มันอธิบายสูตรยาวๆ — เจอสูตรคนอื่นที่ซับซ้อน วางให้ AI ช่วยแปลว่าแต่ละท่อนทำอะไร
• ให้มันเขียน Apps Script ให้ — อันนี้ AI ช่วยได้เยอะ บอกสิ่งที่อยากให้ทำเป็นภาษาคน แล้วเอาโค้ดไปวางใน Apps Script ได้เลย

แต่อย่าลืมว่า AI ก็ตอบผิดได้ ความรู้พื้นฐานจากบทความนี้แหละที่จะช่วยให้เรา เช็กได้ว่าสูตรที่มันให้มาถูกหรือเปล่า ก่อนเอาไปใช้กับเงินจริง

และใครที่อยากติดตามเรื่องราวดีๆ เครื่องมือที่จะช่วยให้ชีวิตคุณง่ายขึ้น ติดตามเราได้ไว้เลย
ฝากเพจ My Money Toolkit ไว้ด้วยนะครับ

อ่านมาถึงตรงนี้ ขอบคุณจากใจจริงๆ เลยนะครับ 🙏

บทความ + ชีตตัวอย่าง + เครื่องมือทั้งหมดในเว็บนี้ เราตั้งใจทำให้ใช้ฟรีกันได้เลย เพราะอยากให้ทุกคนเริ่มจัดการเงินตัวเองได้ง่ายขึ้นจริงๆ

ถ้าบทความนี้พอมีประโยชน์ อยากชวนมา สมัครสมาชิก เป็นกำลังใจ เริ่มแค่ ฿60/เดือน ให้เรามีแรงทำของดีๆ ฟรีๆ ทำคอนเทนต์ดีๆ แบบนี้ต่อไปได้อีกยาวๆ

สมาชิกยังได้ของติดมือกลับไปด้วยนะ — ไม่มีโฆษณากวนใจ, เนื้อหา & เครื่องมือพิเศษเฉพาะสมาชิก, ส่วนลดเครื่องมือตลอดชีพ และอื่นๆ อีกเพียบ

💖 ดูแพ็กสมาชิก / สมัครเลย